Threaded Mode | Linear Mode

Anarch Cassius · 04-30-2012 06:23 AM

Code:

[FUNCTION npccast]

 // Determine spell and skill used to cast

 LOCAL.SPELL = <EVAL <ARGV[0]> &~ 0ff000000>

 LOCAL.SKILL = <EVAL (<STREAT <SERV.SPELL.<LOCAL.SPELL>.SKILLREQ>>) &~ 0ff000000>

 IF (<SERV.SPELL.<LOCAL.SPELL>.MANAUSE> > <MANA>)

    RETURN 1

 ENDIF

 IF (<EVAL STRLEN(<SERV.SPELL(<LOCAL.SPELL>).RUNES>)> > 0)

     SAY <RUNES <LOCAL.SPELL>>

 ENDIF

 IF !(<LOCAL.SKILL>)

  LOCAL.SKILL = 25

 ENDIF

 TAG.LASTCASTING=<eval (<SERV.TIME>+<SERV.SPELL.<LOCAL.SPELL>.CAST_TIME>)>

 TAG.SPELLCASTING=<LOCAL.SPELL>

// Set spell target

IF (<ARGV> > 2) //use coords if given

    ACT = 0

    ACTP = <ARGV[1]>, <ARGV[2]>, <ARGV[3]>, <ARGV[4]>

ELIF (<SERV.SPELL.<LOCAL.SPELL>.FLAGS> & spellflag_targ_xyz) //use coords for ground targ spells regardless

    ACTP = <ACT.P>

    ACT = 0

ELSE

    REF1 = <ARGV[1]>

    IF !(<REF1.UID>)

        REF1 = <ACT.UID>

        IF !(<REF1.UID>)

            REF1 = <UID>

        ENDIF

    ENDIF

    ACT = <REF1.UID>

    ACTP = <REF1.P>

ENDIF

 // Set character action

 ACTPRV = <UID>

 ACTARG1 = <LOCAL.SPELL>

 ACTION = <LOCAL.SKILL>

 RETURN 1

You can't just use CAST, it needs a target. This function works with objects or coordinates.

Code:

npccast s_fart_dart,<act>

Threaded Mode \| Linear Mode Problem with custom spells...
Author	Message