Post Reply 
 
Thread Rating:
  • 1 Votes - 5 Average
  • 1
  • 2
  • 3
  • 4
  • 5
tGolemAssembly
Author Message
Khaos
Master
**

Posts: 595
Likes Given: 166
Likes Received: 83 in 51 posts
Joined: Mar 2012
Reputation: 11



Post: #1
tGolemAssembly
Need some feedback on this. It is going in the Basepacks if it is working alright. The advanced clockworks I am working on now since they don't follow the normal golems guidelines. Just adjust the items and mobile definitions for your server. It should be an EA replica at this point. The Specifications follow the Player made one and not the NPC one you normally fight (There are differences).

This uses Xun's Make my pet btw. You should grab that as well.

Code:
[TypeDef tClockworkAssembly]
On=@DClick
If !(<Src.Tinkering>)
Src.SMsgL -1,1071940    // You are not quite sure how to use this.
Return 1
EndIf
If (<Src.Tinkering> < 700)
Src.SMsgL -1,1071943    // You must be a journeyman or higher tinker to construct a golem.
Return 1
EndIf
If (<Src.Tag0.GolemDelay>)
Src.SMsgL -1,1071942    // You are too drained to make another golem. You must wait approximately one day to construct another.
Return 1
EndIf
If (<TopObj> != <Src.UID>)
Src.SMsgL -1,1071944    // The clockwork assembly must be in your backpack to construct a golem.
Return 1
EndIf
If <Src.CurFollower> > <Eval (<MaxFollowers> - 3)>
Src.SMsgL -1,1049607    // You have too many followers to control that creature.
Return 1
EndIf
If !(<Src.Restest 1 iPowerCrystal>)
Src.SMsgL -1,1071945    // You need a power crystal to construct a golem.
Return 1
ELIf !(<Src.Restest 5 iGears>)
Src.SMsgL -1,1071946    // You need more gears to construct a golem.
Return 1
ElIf !(<Src.Restest 50 iBronzeIngot>)
Src.SMsgL -1,1071947    // You need more bronze ingots to construct a golem.
Return 1
ElIf !(<Src.Restest 50 iIronIngot>)
Src.SMsgL -1,1071948    // You need more iron ingots to construct a golem.
Return 1
EndIf
If (<R1,1000> > <Eval ((<Src.Tinkering> - 700) * 2)>)
Src.SMsgL -1,1071941    // You failed to make the golem.
Return 1
Else
Serv.NewNpc cGolem
New.Fame=10
New.Karma=10
New.OStr=<MulDiv {251 350},<Src.Tinkering>,1000>
New.ODex=<MulDiv {76 100},<Src.Tinkering>,1000>
New.OInt=<MulDiv {101 150},<Src.Tinkering>,1000>
New.MaxHits=<MulDiv {151 210},<Src.Tinkering>,1000>
New.Wrestling=<MulDiv {601 1000},<Src.Tinkering>,1000>
New.Tactics=<MulDiv {601 1000},<Src.Tinkering>,1000>
New.MagisResistance=<MulDiv {1501 1900},<Src.Tinkering>,1000>
New.Parrying=<MulDiv {601 1000},<Src.Tinkering>,1000>
New.ResPhysical={35 55}
New.ResFire={50 60}
New.ResCold={10 30}
New.ResPoison={99 100}
New.ResEnergy={30 40}
New.P=<Src.P>
New.MakeMyPet
Src.CurFollowers += <New.ControlSlots>
Src.Tag.GolemDelay=1
Src.TimerF 864000,GolemDelay    // 24 hours; inclusive of the deciseconds multiplier.
Src.Sound 0241
Update
EndIf

[Function GolemDelay]
Src.Tag.GolemDelay=


[ItemDef iPowerCrystal]
ID=iMagicalCrystal2
Name=power crystal
NameLoc=1112811
Type=tNormal
Weight=1

Category=Resources
Subsection=Golems
Description=Power Crystal


[ItemDef iClockworkAssembly]
ID=iWinch
Name=clockwork assembly
NameLoc=1073426
Type=tClockworkAssembly
Weight=50

Category=Resources
Subsection=Golems
Description=Clockwork Assembly

On=@Create
Color=044E


[ItemDef iLeatherWolfAssembly]
ID=iWinch
Name=leather wolf assembly
NameLoc=1113031
Type=tNormal
SkillMake=Tinkering 1000
Resources=1 iClockworkAssembly,1 iPowerCrystal,2 iVoidEssnce
Weight=50

Category=Resources
Subsection=Golems
Description=Leather Wolf Assembly

On=@Create
Color=044E


[ItemDef iClockworkScorpionAssembly]
ID=iWinch
Name=clockwork scorpion assembly
NameLoc=1113032
Type=tNormal
SkillMake=Tinkering 1000
Resources=1 iClockworkAssembly,1 iPowerCrystal,1 iVoidEssnce
Weight=50

Category=Resources
Subsection=Golems
Description=Clockwork Scorpion Assembly

On=@Create
Color=044E


[ItemDef iVollemAssembly]
ID=iWinch
Name=vollem assembly
NameLoc=1113033
Type=tNormal
SkillMake=Tinkering 1000
Resources=1 iClockworkAssembly,1 iPowerCrystal,3 iVoidEssnce
Weight=50

Category=Resources
Subsection=Golems
Description=Vollem Assembly

On=@Create
Color=044E


[EOF]
(This post was last modified: 03-27-2016 05:22 PM by Khaos.)
03-27-2016 05:19 PM
Find all posts by this user Like Post Quote this message in a reply
Khaos
Master
**

Posts: 595
Likes Given: 166
Likes Received: 83 in 51 posts
Joined: Mar 2012
Reputation: 11



Post: #2
RE: tGolemAssembly
And this should be the standard NPC Golem...

Code:
[Events AIGolem]
On=@SpellEffect
If (<ArgN1> == sHeal) || (<ArgN1> == sGreaterHeal) || (<ArgN1> == sParalyze) || (<ArgN1> == sPoison)
Return 1
EndIf

On=@GetHit
If (<IsPet>)
If (<Owner.Distance> <= 7)
  If (<ArgN1> > <Owner.Mana>)
   Local.Dam=<Eval (<ArgN1> - <Owner.Mana>)>
   Owner.Mana -= <ArgN1>
   Owner.Damage <Local.Dam>,DamGod,<Src.UID>
  Else
   Owner.Mana -= <ArgN1>
  EndIf
EndIf
EndIf

On=@Hit
If !(<R19>)
Src.SMsgL -1,1070696    // You have been stunned by a colossal blow.
If (<Src.Events> == eStunned)
  Src.FindID.iStunMemory.Timer += 10
Else
  Src.Events +eStunned
  Src.Flags &= ~StatFWar
  Src.Flags |= StatFParalyzed
  Serv.NewItem iStunMemory,1,<Src.Equip>
EndIf
EndIf

On=@DeathCorpse
NewLoot=GolemLoot


[Events eStunned]
On=@WarMode
Return 1

On=@SpellCast
Return 1

On=GetHit
ArgN2 |= DamNoUnparalyze
Return


[ItemDef iStunMemory]
ID=iMemory
Name=Stun Memory

On=@Create
Timer=10

On=@Timer
Cont.Events -eStunned
Cont.Flags &= ~StatFParalyzed
Remove
Return 1


[Template GolemLoot]
Category=Templates: NPC Loot
Subsection=Monsters: Mechanical
Description=Golem
Item=iArcaneGem,1,R19
Item=iPowerCrystal,1,R19
Item=iClockworkAssembly,1,R19
Item={RandomCommonMusicBoxGear 75 RandomUncommonMusicBoxGear 24 RandomRareMusicBoxGear 1},1,R19
Item=RandomIngot,{11 25}


[CharDef 02F0]
DefName=cGolem
Name=golem
Can=CanWalk|CanUseHands
MoveRate=100
Dam=13,24
Armor=35,55
Icon=iGolemIcon
Sound=
FoodType=
MaxFood=0
Resources=0
Aversions=tTrap
Desires=tIngot
BloodColor=-1
TEvents=AIGolem

Category=Monsters
Subsection=Mechanical
Description=Golem

On=@Create
NPC=BrainMonster

Fame=3500
Karma=-3500
//Alignment=Evil

DamPhysical=100
DamFire=0
DamCold=0
DamPoison=0
DamEnergy=0

ResPhysical=35,55
ResFire=100
ResCold=10,30
ResPoison=10,25
ResEnergy=30,40

OStr={251 350}
ODex={76 100}
OInt={101 150}
MaxHits={151 210}

Wrestling={601 1000}
Tactics={601 1000}
MagicResistance={1501 1900}
Parrying={601 1000}


[EOF]

Fixed a small typo! ^_^
(This post was last modified: 03-27-2016 07:43 PM by Khaos.)
03-27-2016 07:06 PM
Find all posts by this user Like Post Quote this message in a reply
Post Reply 


Forum Jump:


User(s) browsing this thread: 1 Guest(s)