Threaded Mode | Linear Mode

Jhobean · 08-05-2022 01:36 AM

Ok here an update:
1- on ini you add

Code:

PACKET191=f_orion_exclusif

2- on @login you add

Code:

SENDPACKET B0BF W0007 W0FACE W0034 //Ask version Orion

if (<ACCOUNT.PLEVEL> > 3)

elif ( !(STRCMP(<src.account>,nameofexceptionaccount)) )

else    

    timerf 5,F_DISCONNECT_BADCLIENT

endif

3- You add these function on your script

Code:

[FUNCTION f_orion_exclusif]  //Function déclenché a la réception du packet 

ref1=<LOCAL.CHAR> //(uid) 

// <LOCAL.ACCOUNT> //(string) current active account if any is logged by the client

// on recois ça: 0 11 250 206 0 52 1 0 0 0 (B0BF W000B W0FACE W0034 D0V1V2V3V4) Where V1 V2 V3 V4 - version bytes

//<dlocal.7><dlocal.8><dlocal.9><dlocal.10> if version id 1.0.17.0 it show 10170

IF <local.2> ==11 //Packet de version orion

    IF (<dlocal.7><dlocal.8><dlocal.9><dlocal.10> >= 10170) //Check if the orion version is more than 1.0.17.0

          ref1.ctag.clientconforme=1

    ENDIF

ENDIF

Code:

[FUNCTION F_DISCONNECT_BADCLIENT]

if (!<ctag0.clientconforme>)

    sysmessageua 089 0 0 eng  This server requiere last ORION version

    sysmessageua 089 0 0 eng You will be disconnected....   

   SERV.LOG DECONNECTION of <ACCOUNT> <NAME> not good client

   serv.NEWITEM i_disconnect_now

   new.EQUIP

endif

[FUNCTION DISCONNECT_NOW]
serv.NEWITEM i_disconnect_now
new.EQUIP

Code:

[ITEMDEF i_disconnect_now]

ID    = i_memory

TYPE    = t_eq_script

ON = @Create

   TIMER    = 1

ON = @Timer

   CONT.SYSMESSAGE Disconnection...

   CONT.UPDATE

   CONT.DISCONNECT

   REMOVE

   return 1

Atilla209 · 08-05-2022 02:16 AM

Oh you are a god!
thank you! Love

yeoldesphere · 08-28-2022 06:28 AM

reply number 2

Extreme · (06-22-2024)

Here is the Jhobean's updated code.

Spoiler (Click to View)

Code:

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

// Script Name: Orion Features

// Version: 1.0.0

// Authors: 

//   - Jhobean (https://github.com/Jhobean)

//   - EXTREME (https://github.com/GODEXTREME)

//

// Creation Date: June 8, 2024

// 

// Description:

// This script should be used if you want to force your players to use Orion Client and to control the features they can use.

// 

// Usage Instructions:

// 1. Go to sphere.ini and add anywhere: PACKET191=F_ORION_PACKET_RECEIVE.

// 2. Go to sphere.ini and add in EVENTSPLAYER: E_ORION_FEATURES

// 2. Set on ORION.VERSION the mininum Orion Version allowed to play on your server.

// 3. Go to Orion Launcher, select the tab "For server administrators".

// 3.1 Under "Orion features" tab, select all features will be allowed (check) and copy the last part of the code on the text box

//       under Sphere tab, and set on ORION.FEATURES.

// 3.2 Under "OA Features" tab, select all all features will be allowed (check) and copy the last 4 parts of the code on the text

//       box under Sphere tab, and set on ORION.OAFEATURES.

// 

// Version History:

// 1.0.0: [06/08/2024] - Initial release.

// 

// Additional Notes:

// The packet B0BF (191) is used for many functions. If you have any other function that uses this packet, you

// must copy the code under [FUNCTION F_ORION_PACKET_RECEIVE] and place into your original packet B0BF

// handle function.

//

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

[DEFNAME ORION]

ORION.VERSION 10330                                                // Minimum Orion Client Version

ORION.FEATURES D0FF963CF5                                         // Allowed Orion Features

ORION.OAFEATURES D0FFFFFFFF D0EBFF8677 D0FFFFFE7F D0FFBFEFFF    // Allowed Orion Assistant Features

ORION.DISCONNECT 1                                                // 1 - Disconnect if player not using Orion

ORION.DISCONNECT.TIME 5                                            // Seconds to disconnect players without proper Orion version

[EVENTS E_ORION_FEATURES]

ON=@LOGIN

F_ORION_ONLOGIN

[FUNCTION F_ORION_ONLOGIN]

CTAG0.ORIONCLIENT

SENDPACKET B0BF W0007 W0FACE W00034                         // Ask for Orion Client Version

SENDPACKET B0BF W000B W0FACE W00032 <DEF.ORION.FEATURES>    // Send Allowed Orion Features

SENDPACKET B0BF W0017 W0FACE W08001 <DEF.ORION.OAFEATURES>    // Send Allowed Orion Assistant Features

IF (<ACCOUNT.PLEVEL> > 3)

ELIF (!STRCMP(<ACCOUNT>,youraccountname))

ELSEIF (<dDEF.ORION.DISCONNECT>)

    TIMERF <dDEF.ORION.DISCONNECT.TIME>,F_DISCONNECT_BADCLIENT

ENDIF

RETURN 0

[FUNCTION F_ORION_PACKET_RECEIVE]

REF1 <LOCAL.CHAR>

IF (<dLOCAL.2> == 11)

  IF (<dLOCAL.7><dLOCAL.8><dLOCAL.9><dLOCAL.10> >= <dDEF.ORION.VERSION>)

    REF1.CTAG0.ORIONCLIENT 1

  ENDIF

ENDIF

RETURN 0

[FUNCTION F_DISCONNECT_BADCLIENT]

IF (!<CTAG0.ORIONCLIENT>)

  SYSMESSAGEUA 089 0 0 eng This server requires the latest ORION version

  SYSMESSAGEUA 089 0 0 eng You will be disconnected...

  SERV.LOG DISCONNECTION OF <ACCOUNT> <NAME> USING OLDER ORION VERSION

  DISCONNECT_NOW

ENDIF

RETURN 0

[FUNCTION DISCONNECT_NOW]

SERV.NEWITEM I_DISCONNECT_NOW

NEW.EQUIP

RETURN 0

[ITEMDEF I_DISCONNECT_NOW]

ID=I_MEMORY

TYPE=T_EQ_SCRIPT

ON=@CREATE

TIMER=1

ON=@EQUIP

TIMER=1

ON=@TIMER

CONT.UPDATE

CONT.DISCONNECT

REMOVE

RETURN 1

Orion Features.scp (Size: 3.44 KB / Downloads: 3)

Cellerium · 12-27-2024 03:19 AM

thanks for that! very good

Stern · 02-10-2025 02:02 AM

thanks for that!

Threaded Mode \| Linear Mode Forcing Orion Client
Author	Message