[ITEMDEF i_lich_form_degen]
ID=i_memory
TYPE=T_EQ_SCRIPT
NAME=Lich Form

ON=@Timer
IF (<EVAL <CONT.HITS>-1> >= 1)
CONT.HITS --
ENDIF
TIMER=2
RETURN 1

[EVENTS e_lich_form]
ON=@Death
BODY=<OBODY>
TAG0.BONUSMANAREGEN -= 13
	IF (<TAG0.BONUSMANAREGEN> == 0)
	TAG.BONUSMANAREGEN=
	ENDIF
MODAR += 10
FINDID.i_lich_form_degen.REMOVE
EVENTS -e_lich_form

ON=@GetHit
IF (<SRC.ISCHAR>)
	IF (!(<ISEMPTY <SRC.TAG.SLAYERGROUP>>))
		IF (STRMATCH(<SRC.TAG.SLAYERGROUP>,Undead))
		ARGN1 *= 2
		ENDIF
	ENDIF
ENDIF

[Spell 107]
DEFNAME=s_Lich_Form
NAME=Lich Form
SOUND=0
RUNES=
CAST_TIME=2.0
RESOURCES=1 i_reag_daemon_blood,1 i_reag_nox_crystal,1 i_reag_grave_dust
RUNE_ITEM=0
SCROLL_ITEM=0
FLAGS=spellflag_playeronly
EFFECT_ID=
EFFECT=
DURATION=0.0
MANAUSE=23
SKILLREQ=SKILL_NECROMANCY 70.0
INTERRUPT=0.0,0.0

ON=@Start
IF (<ISPLAYER>)
SAY @,3,1 Rel Xen Corp Ort
ENDIF

ON=@Effect
IF (<BODY> == c_liche)
BODY=<OBODY>
TAG0.BONUSMANAREGEN -= 13
	IF (<TAG0.BONUSMANAREGEN> == 0)
	TAG.BONUSMANAREGEN=
	ENDIF
MODAR += 10
FINDID.i_lich_form_degen.REMOVE
EVENTS -e_lich_form
UPDATE
ELIF (<ISHUMAN>)
EVENTS +e_lich_form
SERV.NEWITEM i_lich_form_degen,1,<UID>
NEW.TIMER=2
TAG0.BONUSMANAREGEN += 13
MODAR -= 10
BODY=c_liche
UPDATE
ENDIF
SOUND=019C
EFFECT=3,03709,16,30,3,1108

[EOF]