//===========FIXED Potion Keg=========== 
// future addition: change Keg color to Potion color when it's added. 

[ITEMDEF i_keg_potion]
NAME=Empty Keg
ID=01ad6
TYPE=t_script
VALUE=40
WEIGHT=40
DYE=1
SKILLMAKE=SKILL_TINKERING 50.0,SKILL_CARPENTRY 50.0
RESOURCES=15 i_log,6 i_ingot_iron

ON=@ClientToolTip
IF (<MORE>)
SRC.ADDCLILOC 1060658,<SERV.ITEMDEF.<MORE>.NAME>,<dMORE2>
ENDIF

ON=@DropON_Self
IF (!(<MORE>))
	IF (<ARGO.TYPE> == T_POTION)
	MORE=<ARGO.BASEID>
	MORE2=<ARGO.AMOUNT>
	SRC.CREATEITEM i_bottle_empty,<ARGO.AMOUNT>
	ARGO.CONSUME <ARGO.AMOUNT>
	NAME=Potion Keg
	RESENDTOOLTIP 1
	ELSE
	MESSAGE @88 You must drop a potion!
	ENDIF
ELIF (<ARGO.BASEID> == <MORE>)
	IF (<EVAL <MORE2>+<ARGO.AMOUNT>> <= 200)
	MORE2 += <ARGO.AMOUNT>
	SRC.CREATEITEM i_bottle_empty,<ARGO.AMOUNT>
	ARGO.CONSUME <ARGO.AMOUNT>
	RESENDTOOLTIP 1
	ELSE
	MESSAGE @,,2 502233
	ENDIF
ENDIF
RETURN 1

ON=@DClick
IF (!(<MORE>))
MESSAGE @,,2 502222
RETURN 1
ELSE
TARGET @,,2 502241
RETURN 1
ENDIF

ON=@Targon_Item
IF (<SRC.TARG.BASEID> != i_bottle_empty)
MESSAGE @,,2 502227
ELIF (<SRC.TARG.TOPOBJ.UID> != <SRC.UID>)
MESSAGE @,,2 502224
ELSE
	IF (<SRC.TARG.AMOUNT> >= <MORE2>)
	SERV.NEWITEM <MORE>,<MORE2>
	NEW.BOUNCE
	SRC.TARG.CONSUME <MORE2>
	MORE2=0
	MORE=0
	ELSE
	SERV.NEWITEM <MORE>,<SRC.TARG.AMOUNT>
	NEW.BOUNCE
	MORE2 -= <SRC.TARG.AMOUNT>
	SRC.TARG.CONSUME <SRC.TARG.AMOUNT>
	ENDIF
SRC.SYSMESSAGE @,,2 502242
	IF (!(<MORE2>))
		IF (!(<R30>))
		SRC.SYSMESSAGE @,,2 502259
		CONSUME 1
		ENDIF
	ENDIF
RESENDTOOLTIP 1
ENDIF
RETURN 1

//=========INVIS Potion

[ITEMDEF i_potion_Invisibility] 
ID=i_bottle_WHITE 
NAME=Invisibility 
TYPE=T_POTION 
TDATA1=i_bottle_empty 
RESOURCES=i_reag_worm_heart 4, i_bottle_EMPTY 
SKILLMAKE=SKILL_ALCHEMY 65.1 
VALUE=60

ON=@Create 
MORE1=s_invisibility 
MORE2=100.0 
COLOR=0191 

[EOF]