[Spell 202]
DEFNAME=s_Close_Wounds
NAME=Close Wounds
SOUND=0202
RUNES=
CAST_TIME=1.5
RESOURCES=
RUNE_ITEM=0
SCROLL_ITEM=0
FLAGS=spellflag_targ_char|spellflag_fx_targ|spellflag_good|spellflag_no_castanim|spellflag_playeronly
EFFECT_ID=0376A
EFFECT=10
DURATION=0.0
MANAUSE=10
SKILLREQ=SKILL_CHIVALRY 0.0
INTERRUPT=0.0,0.0

ON=@Start
SAY @,,2 1060719

ON=@Success
IF (<ACT.DISTANCE> > 2)
SYSMESSAGELOC -1,1060178
RETURN 1
ELIF (<ACT.FLAGS>&STATF_PET) && (<ACT.FLAGS>&STATF_INVUL)
SYSMESSAGELOC -1,1060177
RETURN 1
ELIF (((<ACT.FLAGS>&STATF_Poisoned) || (<ACT.TAG0.MORTALWOUNDED>)) && (<ACT.UID> == <UID>))
MESSAGE @,,2 1005000
RETURN 1
ELIF ((<ACT.FLAGS>&STATF_Poisoned) || (<ACT.TAG0.MORTALWOUNDED>))
ACT.MESSAGE @,,2 1010398
RETURN 1
ELIF (<ACT.HITS> >= <ACT.MAXHITS>)
SYSMESSAGELOC -1,500955
RETURN 1
ENDIF

ON=@Effect
IF (<tag0.mortalwounded>) || (<flags>&statf_poisoned)
src.sysmessageloc -1,500951
return 1
ENDIF
LOCAL.TOHEAL=<EVAL <SRC.F_COMPUTE_POWERLEVEL 6>+<R0,2>>
IF (<LOCAL.TOHEAL> < 7)
LOCAL.TOHEAL=7
ELIF (<LOCAL.TOHEAL> > 39)
LOCAL.TOHEAL=39
ENDIF
IF (<EVAL <LOCAL.TOHEAL>+<HITS>> > <MAXHITS>)
LOCAL.TOHEAL=<EVAL <MAXHITS>-<HITS>>
ENDIF
HITS += <LOCAL.TOHEAL>
SYSMESSAGELOC -1,1060203,<dLOCAL.TOHEAL>
EFFECT 2,03779,3,30

[EOF]