[ITEMDEF i_deed_lucky_dealer]
ID=i_deed
NAME=Lucky Dealer Contract of Employment
TYPE=T_NORMAL
VALUE=500

ON=@Create
COLOR=0482
ATTR=attr_newbie

ON=@Dclick
IF (<CONT> != <SRC.FINDLAYER.layer_pack>)
SRC.SYSMESSAGELOC -1,1060640
ELSE
	IF (!(<UID.<CONT.REGION.UID>.ISAMULTI>))
	SRC.SYSMESSAGELOC -1,503239
	ELIF (<UID.<CONT.REGION.UID>.MORE1> != <SRC>)
	SRC.SYSMESSAGELOC -1,1062423
	ELSE
	SERV.NEWNPC=C_LUCKY_DEALER
	NEW.P=<SRC.P>
	NEW.UPDATEX
	NEW.REMOVETIMER=<EVAL 60*60*24*2>
	SRC.SYSMESSAGELOC -1,1062698,<NEW.NAME>
	CONSUME 1
	ENDIF
ENDIF
RETURN 1

[CHARDEF C_LUCKY_DEALER]
NAME=#NAMES_HUMANMALE the lucky dealer
ID=C_MAN
DESIRES=i_gold
CAN=MT_USEHANDS|MT_EQUIP|MT_FIRE_IMMUNE|MT_NONMOVER
TSPEECH=VENDORS
ARMOR=100

on=@create
COLOR=colors_skin
STR=1
INT=0
DEX=0
FAME=0
KARMA=0
FLAGS |= statf_invul
ALLSKILLS=0.0
EQUIPHALO
WEARNPCVENDOR

ON=@Dclick
SAY @,,2 1076071,<SRC.NAME>,1,100,1,<R1,100>
RETURN 1

[EOF]
