[CHARDEF c_mallyx]
ID=c_dragon_green
NAME=Mallyx the Uniyelding
SOUND=snd_MONSTER_DRAGON1
ICON=i_pet_DRAGON
ANIM=03f9c7f
CAN=MT_WALK|MT_FLY
DAM=31,37
ARMOR=80
RESOURCES=50 i_ribs_raw,8 i_reag_dragon_blood, 20 i_hide_dragon_green
FOODTYPE=80 t_meat_raw,t_gem
DESIRES=i_gold
AVERSIONS=r_water,r_civilization
TEVENTS=e_carnivores3
CATEGORY=Monsters
SUBSECTION=Dragons and Drakes
DESCRIPTION=Mallyx

ON=@Create
NPC=brain_dragon
FAME=10000
KARMA=-10000
COLOR=0591
STR=950
MAXHITS=4050
DEX={285 300}
INT={335 475}
PARRYING=780
MAGICRESISTANCE=1150
TACTICS=1200
ANATOMY=80.0
WRESTLING=1200

ON=@NPCRestock
ITEM=loot_DRAGON
ITEM=i_moonstone,1,R10

[CHARDEF c_gregorio_the_brigand]
NAME=Gregorio the Brigand
ID=C_MAN
DAM=17,33
ARMOR=30
DESIRES=i_gold,e_notoriety
AVERSIONS=t_TRAP,t_eerie_stuff
TSPEECH=spk_human_prime
TSPEECH=jobBrigand
TSPEECH=spk_needs
TSPEECH=spk_rehello
TSPEECH=spk_human_default
TEVENTS=e_Human_HearUnk
TEVENTS=e_Human_Needs
TEVENTS=e_Human_ConvInit
TEVENTS=e_Human_Greet
TEVENTS=e_Human_Space
TEVENTS=e_Human_Refuse
TEVENTS=e_Human_Environ

ON=@Create
COLOR=colors_skin
STR={96 110}
DEX={81 95}
INT={61 75}
FAME=1500
KARMA=-3000
CAMPING={45.0 68.0}
POISONING={35.0 58.0}
SNOOPING={35.0 58.0}
LockPicking={35.0 58.0}
STEALING={45.0 68.0}
FENCING={45.0 68.0}
PARRYING={55.0 78.0}
SWORDSMANSHIP={35.0 58.0}
WRESTLING={35.0 58.0}
MACEFIGHTING={25.0 48.0}
TACTICS={55.0 78.0}
NPC=brain_thief
ITEMNEWBIE=random_male_hair
COLOR=colors_hair
ITEMNEWBIE=random_facial_hair
COLOR=match_hair

ON=@NPCRestock
ITEM=RANDOM_LIGHT
ITEM=I_SHIRT_PLAIN
COLOR=colors_all
ITEM=random_pants
COLOR=colors_all
ITEM=random_shoes
COLOR=colors_neutral
ITEM=random_weapon
ITEM=random_coin_purse

ON=@DeathCorpse
DORAND 2
NEWLOOT=i_servered_elf_ears
NEWLOOT=i_servered_human_ears
ENDDO

[CHARDEF c_deldrimor]
ID=C_SPIDER_LORD
NAME=Deldrimor, Spirit of Desease
ARMOR=70
DAM=21,26

ON=@Create
NPC=brain_monster
STR=500
DEX=1000
INT=900
MAXHITS=5250
WRESTLING=110.0
TACTICS=110.0
ANATOMY=110.0
MAGICRESISTANCE=100.0
EVALUATINGINTEL=120.0
MAGERY=105.0
KARMA=-10000
FAME=9000

ON=@Hit
IF (<FLOATVAL 0.05> <RANDOMDOUBLE>)
SRC.SPELLEFFECT S_POISON,90.0,<UID>
ENDIF

ON=@GetHit
IF (<FLOATVAL 0.0875> > <RANDOMDOUBLE>)
LOCAL.OLDNEW=<NEW>
SERV.NEWNPC C_DREAD_SPIDER
NEW.REMOVETIMER=60*10
NEW=<LOCAL.OLDNEW>
ENDIF

ON=@Death
IF (<ATTACKER>)
LOCAL.OLDNEW=<NEW>
REF1=<ATTACKER.MAX>
	IF (<REF1>)
	SERV.NEWITEM i_staff_gnarled
	NEW.NAME=Deldrimor's Leg
	NEW.TAG.MAGICDAMINCREASE=15
	NEW.TAG.HITCHANCEDECREASE=10
	NEW.GIVEITEMEVENT T_PROPRIEDADES
	NEW.GIVEITEMEVENT t_status_bonus
	NEW.TAG.MANAREGENERATION=3
	NEW.TAG.SPELLCHANNELING=1
	NEW.TAG.LOWERREAGENTCOST=8
	NEW.SETSLAYER
	NEW.TAG.SLAYERGROUP=Spider
		IF (<REF1.FLAGS>&STATF_PET)
		REF1=<REF1.OWNER>
		ENDIF
	REF1.BOUNCE <NEW>
	SERV.NEWITEM i_osi_treasure_map
	REF1.BOUNCE <NEW>
	SERV.NEWITEM i_osi_treasure_map
	REF1.BOUNCE <NEW>
	ENDIF
	FOR y 0 <EVAL <ATTACKER>-1>
		IF (<ATTACKER.<dLOCAL.Y>>)
		REF402=<ATTACKER.<dLOCAL.Y>>
			IF (<REF402.FLAGS>&STATF_PET)
			REF402=<REF402.MEMORYFINDTYPE.memory_ipet.LINK>
			ENDIF
		REF402.NEWGOLD 7500
		REF402.GO Help Room
		ENDIF
	ENDFOR
NEW=<LOCAL.OLDNEW>
ENDIF

[EOF]