[CHARDEF c_personalizer]
DEFNAME=c_personalizer
ID=c_man
NAME=#NAMES_HUMANMALE the Personalizer
DAM=0
ARMOR=15
CAN=MT_WALK|MT_RUN|MT_EQUIP
TSPEECH spk_personalizer

ON=@Create
COLOR=colors_skin
str={80 120}
dex={80 120}
int={80 120}
allskills=100.0

ON=@NPCRESTOCK
ITEM=random_male_hair
color=36
ITEM=random_hats
ITEM=random_footwear
ITEM=random_male_pants
ITEM=random_over_armor
ITEM=i_lantern
MOREY=1
TIMER=-1

ON=@NpcSeeNewPlayer
say @946,3,1 You can put your name on an item for just 50,000 gold. Just say "personalize" to me.

[SPEECH spk_personalizer]
ON=*personalize*
src.targetf personalize_name
say @946,3,1 Target the item.

[FUNCTION personalize_name]
IF (<ARGO.ISITEM>)
IF (<argo.topobj.uid>!=<uid>)
sysmessage @04,3,1 The item must be in your backpack.
return 1
ENDIF
IF (<ARGO.TAG0.NOVENDOR>) || (<ARGO.TAG0.UNIQUEITEM>)
sysmessage @04,3,1 This item can not be personalized.
RETURN 1
ENDIF
IF (<argo.topobj.uid>==<uid>)
IF (<gold> >= 50000)
ARGO.name=<name>'s <argo.name>
ARGO.resendtooltip 1
gold -= 50000
ELSE
sysmessage @946,3,1 You don't have 50,000 gold coins.
ENDIF
ENDIF
ELSE
SYSMESSAGE @946,3,1 You must target an item!
ENDIF

[EOF]