[FUNCTION ENCOMENDA]
IF (<<ARGN1>> < 0.1)
SYSMESSAGE @946,3,1 You must have at least 0.1 in <SERV.SKILL.<ARGN1>.KEY>.
ELIF !(<FINDID.i_bulk_request_timer>)
SERV.NEWITEM i_bulk_request_timer
NEW.MORE1=<ARGN1>
EQUIP <NEW>
SERV.NEWITEM i_bulk_order_deed
BOUNCE <NEW>
NEW.TAG.VENDORID=<UID.<VAR0.BULKORDERVENDORID>.BASEID>
VAR.BULKORDERVENDORID
NEW.MOREZ=<ARGN1>
NEW.MORE1=<HVAL {10 1 15 1 20 1}>
	IF (<ARGN1> == 34)
	NEW.COLOR=023c
		IF (<<ARGN1>> <= 70.0)
		TRYSRC <UID> NEW.BULKITEMSELECTTAILOR
		ELSE
		TRYSRC <UID> NEW.BULKITEMSELECTTAILOR 1
		ENDIF
	ELIF (<ARGN1>==7)
		IF (<<ARGN1>> <= 70.0)
		TRYSRC <UID> NEW.BULKITEMSELECTBS
		ELSE
		TRYSRC <UID> NEW.BULKITEMSELECTBS 1
		ENDIF
	ELIF !(<ARGN1>)
	NEW.COLOR=020b
		IF (<<ARGN1>> <= 70.0)
		TRYSRC <UID> NEW.BULKITEMSELECTALCH
		ELSE
		TRYSRC <UID> NEW.BULKITEMSELECTALCH 1
		ENDIF
	ELIF (<ARGN1>==8)
	NEW.COLOR=0175
		IF (<<ARGN1>> <= 70.0)
		TRYSRC <UID> NEW.BULKITEMSELECTBC
		ELSE
		TRYSRC <UID> NEW.BULKITEMSELECTBC 1
		ENDIF
	ENDIF
ELSE
SYSMESSAGE @946,3,1 You still need to wait <EVAL <FINDID.i_bulk_request_timer.TIMER>/60> minutes to get another deed.
ENDIF
VAR.BULKORDERVENDORID

///////////////////////////////////

[FUNCTION BULKITEMSELECTALCH]
IF !(<ARGN1>)
IF !(<R3>)
FOR 4
MORE2 ++
SETBULKALCHEASY <LOCAL._FOR>
ENDFOR
NAME=Large Bulk Order Deed
ELSE
SETBULKALCHEASY 1
LOCAL.NEW=<NEW>
SERV.NEWITEM=<TAG0.ITEM1>
IF !(<NEW.COLOR> >= 1000)
TAG.COR=<NEW.COLOR>
ELSE
TAG.COR=<EVAL <NEW.COLOR>+1>
ENDIF
NEW.REMOVE
NEW=<LOCAL.NEW>
MORE2=1
ENDIF
ELSE
IF (<SRC.ALCHEMY> >= 70.0)
LOCAL.RAND=50
ELSE
LOCAL.RAND=70
ENDIF
IF (<R100> > <LOCAL.RAND>)
FOR 4
MORE2 ++
DORAND 3
SETBULKALCHHARD <LOCAL._FOR>
SETBULKALCHEASY <LOCAL._FOR>
SETBULKALCHHARD <LOCAL._FOR>
ENDDO
ENDFOR
NAME=Large Bulk Order Deed
ELSE
DORAND 3
SETBULKALCHHARD 1
SETBULKALCHEASY 1
SETBULKALCHHARD 1
ENDDO
LOCAL.NEW=<NEW>
SERV.NEWITEM=<TAG0.ITEM1>
IF !(<NEW.COLOR> >= 1000)
TAG.COR=<NEW.COLOR>
ELSE
TAG.COR=<EVAL <NEW.COLOR>+1>
ENDIF
NEW.REMOVE
NEW=<LOCAL.NEW>
MORE2=1
ENDIF
ENDIF

[FUNCTION SETBULKALCHEASY]
DORAND 16
TRY TAG.ITEM<ARGN1>=i_potion_agility
TRY TAG.ITEM<ARGN1>=i_potion_agilitygreat
TRY TAG.ITEM<ARGN1>=i_potion_cureless
TRY TAG.ITEM<ARGN1>=i_potion_cure
TRY TAG.ITEM<ARGN1>=i_potion_explosionless
TRY TAG.ITEM<ARGN1>=i_potion_explosion
TRY TAG.ITEM<ARGN1>=i_potion_healless
TRY TAG.ITEM<ARGN1>=i_potion_heal
TRY TAG.ITEM<ARGN1>=i_potion_nightsight
TRY TAG.ITEM<ARGN1>=i_potion_poisonless
TRY TAG.ITEM<ARGN1>=i_potion_poison
TRY TAG.ITEM<ARGN1>=i_potion_poisongreat
TRY TAG.ITEM<ARGN1>=i_potion_refresh
TRY TAG.ITEM<ARGN1>=i_potion_refreshtotal
TRY TAG.ITEM<ARGN1>=i_potion_strength
TRY TAG.ITEM<ARGN1>=i_potion_strengthgreat
ENDDO

[FUNCTION SETBULKALCHHARD]
DORAND 4
TRY TAG.ITEM<ARGN1>=i_potion_curegreat
TRY TAG.ITEM<ARGN1>=i_potion_explosiongreat
TRY TAG.ITEM<ARGN1>=i_potion_healgreat
TRY TAG.ITEM<ARGN1>=i_potion_poisondeadly
ENDDO

///////////////////////////////////

[FUNCTION BULKITEMSELECTTAILOR]
IF !(<ARGN1>)
	IF !(<R3>)
		FOR 4
		MORE2 ++
		SETBULKTAILOREASY 0 <LOCAL._FOR>
		ENDFOR
	NAME=Large Bulk Order Deed
	ELSE
	SETBULKTAILOREASY 0 1
	MORE2=1
	ENDIF
ELSE
	IF (<SRC.TAILORING> >= 70.0)
	LOCAL.RAND=50
	ELSE
	LOCAL.RAND=70
	ENDIF
	IF (<R100> > <LOCAL.RAND>)
		FOR 4
		MORE2 ++
		SETBULKTAILOREASY 0 <LOCAL._FOR>
		ENDFOR
	NAME=Large Bulk Order Deed
	ELSE
		IF (<R2>)
			DORAND 2
			SETBULKTAILOREASY 0 1
			SETBULKTAILORHARD 1
			ENDDO
		MORE2=1
		ELSE
			FOR 4
				DORAND 3
				SETBULKTAILORHARD <LOCAL._FOR>
				SETBULKTAILOREASY 0 <LOCAL._FOR>
				SETBULKTAILORHARD <LOCAL._FOR>
				ENDDO
			MORE2 ++
			NAME=Large Bulk Order Deed
			ENDFOR
		ENDIF
		IF !(<R3>)
		MOREY=1
		ENDIF
	ENDIF
ENDIF

[FUNCTION SETBULKTAILORHARD]
DORAND 16
TRY TAG.ITEM<ARGN1>=i_dragon_cap
TRY TAG.ITEM<ARGN1>=i_dragon_tunic
TRY TAG.ITEM<ARGN1>=i_dragon_leggings
TRY TAG.ITEM<ARGN1>=i_dragon_gorget
TRY TAG.ITEM<ARGN1>=i_dragon_gloves
TRY TAG.ITEM<ARGN1>=i_terathan_cap
TRY TAG.ITEM<ARGN1>=i_terathan_tunic
TRY TAG.ITEM<ARGN1>=i_terathan_leggings
TRY TAG.ITEM<ARGN1>=i_terathan_gorget
TRY TAG.ITEM<ARGN1>=i_terathan_gloves
TRY TAG.ITEM<ARGN1>=i_robe_healing
ENDDO

[FUNCTION SETBULKTAILOREASY]
DORAND 33
TRY TAG.ITEM<ARGN2>=i_boots_calf
TRY TAG.ITEM<ARGN2>=i_sandals
TRY TAG.ITEM<ARGN2>=i_shoes_plain
TRY TAG.ITEM<ARGN2>=i_boots_thigh
TRY TAG.ITEM<ARGN2>=i_bonnet
TRY TAG.ITEM<ARGN2>=i_cap
TRY TAG.ITEM<ARGN2>=i_hat_feather
TRY TAG.ITEM<ARGN2>=i_hat_floppy
TRY TAG.ITEM<ARGN2>=i_hat_jester
TRY TAG.ITEM<ARGN2>=i_hat_straw
TRY TAG.ITEM<ARGN2>=i_hat_straw_tall
TRY TAG.ITEM<ARGN2>=i_hat_tricorne
TRY TAG.ITEM<ARGN2>=i_hat_wide_brim
TRY TAG.ITEM<ARGN2>=i_hat_wizards
TRY TAG.ITEM<ARGN2>=i_bandana
TRY TAG.ITEM<ARGN2>=i_sash
TRY TAG.ITEM<ARGN2>=i_apron_full
TRY TAG.ITEM<ARGN2>=i_apron_half
TRY TAG.ITEM<ARGN2>=i_skull_cap
TRY TAG.ITEM<ARGN2>=i_kilt
TRY TAG.ITEM<ARGN2>=i_pants_long
TRY TAG.ITEM<ARGN2>=i_skirt_long
TRY TAG.ITEM<ARGN2>=i_pants_short
TRY TAG.ITEM<ARGN2>=i_cape
TRY TAG.ITEM<ARGN2>=i_doublet
TRY TAG.ITEM<ARGN2>=i_dress_full
TRY TAG.ITEM<ARGN2>=i_shirt_fancy
TRY TAG.ITEM<ARGN2>=i_jester_suit
TRY TAG.ITEM<ARGN2>=i_dress_plain
TRY TAG.ITEM<ARGN2>=i_shirt_plain
TRY TAG.ITEM<ARGN2>=i_robe
TRY TAG.ITEM<ARGN2>=i_surcoat
TRY TAG.ITEM<ARGN2>=i_tunic
ENDDO

///////////////////////////////////

[FUNCTION BULKITEMSELECTBS]
IF !(<ARGN1>)
	IF !(<R3>)
		FOR 4
		MORE2 ++
		SETBULKBSEASY 0 <LOCAL._FOR>
		ENDFOR
		NAME=Large Bulk Order Deed
	ELSE
	SETBULKBSEASY 0 1
	MORE2=1
	ENDIF
ELSE
	IF (<SRC.BLACKSMITHING> >= 70.0)
	LOCAL.RAND=50
	ELSE
	LOCAL.RAND=70
	ENDIF
	IF (<R100> > <LOCAL.RAND>)
		IF !(<R2>)
			FOR 4
			MORE2 ++
			SETBULKBSEASY 0 <LOCAL._FOR>
			ENDFOR
		NAME=Large Bulk Order Deed
		ELSE
		SETBULKBSEASY 0 1
		MORE2=1
		ENDIF
	ELSE
		IF (<R3>)
		CALL SETBULKBSEASY 1 1
		MORE2=1
		ELSE
			FOR 4
			CALL SETBULKBSEASY 1 <dLOCAL._FOR>
			MORE2 ++
			ENDFOR
		NAME=Large Bulk Order Deed
		ENDIF
		IF !(<R3>)
		MOREY=1
		ENDIF
	ENDIF
ENDIF

[FUNCTION SETBULKBSEASY]
DORAND 38
TRY TAG.ITEM<ARGN2>=i_scimitar
TRY TAG.ITEM<ARGN2>=i_sword_long
TRY TAG.ITEM<ARGN2>=i_sword_viking
TRY TAG.ITEM<ARGN2>=i_chainmail_coif
TRY TAG.ITEM<ARGN2>=i_chainmail_leggings
TRY TAG.ITEM<ARGN2>=i_chainmail_tunic
TRY TAG.ITEM<ARGN2>=i_ringmail_gloves
TRY TAG.ITEM<ARGN2>=i_ringmail_tunic
TRY TAG.ITEM<ARGN2>=i_ringmail_sleeves
TRY TAG.ITEM<ARGN2>=i_ringmail_leggings
TRY TAG.ITEM<ARGN2>=i_axe_battle_large
TRY TAG.ITEM<ARGN2>=i_katana
TRY TAG.ITEM<ARGN2>=i_kryss
TRY TAG.ITEM<ARGN2>=i_spear_short
TRY TAG.ITEM<ARGN2>=i_war_fork
TRY TAG.ITEM<ARGN2>=i_mace_war
TRY TAG.ITEM<ARGN2>=i_helm_closed
TRY TAG.ITEM<ARGN2>=i_dagger
TRY TAG.ITEM<ARGN2>=i_helm_open
TRY TAG.ITEM<ARGN2>=i_bascinet
TRY TAG.ITEM<ARGN2>=i_helm_nose
TRY TAG.ITEM<ARGN2>=i_platemail_arms
TRY TAG.ITEM<ARGN2>=i_platemail_leggings
TRY TAG.ITEM<ARGN2>=i_platemail_helm
TRY TAG.ITEM<ARGN2>=i_platemail_gorget
TRY TAG.ITEM<ARGN2>=i_platemail_gloves
TRY TAG.ITEM<ARGN2>=i_platemail_chest
TRY TAG.ITEM<ARGN2>=i_hammer_war
TRY TAG.ITEM<ARGN2>=i_maul
TRY TAG.ITEM<ARGN2>=i_hammer_pick
TRY TAG.ITEM<ARGN2>=i_halberd
TRY TAG.ITEM<ARGN2>=i_cutlass
TRY TAG.ITEM<ARGN2>=i_axe_two_hand
TRY TAG.ITEM<ARGN2>=i_shield_round_bronze
TRY TAG.ITEM<ARGN2>=i_shield_buckler
TRY TAG.ITEM<ARGN2>=i_shield_kite_metal
TRY TAG.ITEM<ARGN2>=i_shield_heater
TRY TAG.ITEM<ARGN2>=i_shield_round_metal
ENDDO
IF (<ARGN1>)
	DORAND 6
	TAG.MATERIALTOBEMADE=valorite
	TAG.MATERIALTOBEMADE=verite
	TAG.MATERIALTOBEMADE=gold
	TAG.MATERIALTOBEMADE=agapite
	TAG.MATERIALTOBEMADE=silver
	TAG.MATERIALTOBEMADE=copper
	ENDDO
TAG.COR=<DEF.color_o_<TAG.MATERIALTOBEMADE>>
ENDIF

//////////////////////////////////////

[FUNCTION BULKITEMSELECTBC]
IF !(<ARGN1>)
IF !(<R3>)
FOR 4
MORE2 ++
SETBULKBCEASY <LOCAL._FOR>
ENDFOR
NAME=Large Bulk Order Deed
ELSE
SETBULKBCEASY 1
MORE2=1
ENDIF
ELSE
IF (<SRC.BOWCRAFT> >= 70.0)
LOCAL.RAND=50
ELSE
LOCAL.RAND=70
ENDIF
IF (<R100> > <LOCAL.RAND>)
IF !(<R2>)
FOR 4
MORE2 ++
SETBULKBCEASY <LOCAL._FOR>
ENDFOR
NAME=Large Bulk Order Deed
ELSE
SETBULKBCEASY 1
MORE2=1
ENDIF
ELSE
IF (<R3>)
SETBULKBCEASY 1
IF !(<MOREX>)
MOREX=<SERV.ITEMDEF.<TAG0.ITEM1>.RESOURCES.1.KEY>
ENDIF
MORE2=1
ELSE
FOR 4
SETBULKBCEASY <LOCAL._FOR>
MORE2 ++
ENDFOR
NAME=Large Bulk Order Deed
IF !(<R3>)
MOREY=1
ENDIF
ENDIF
ENDIF
ENDIF

[FUNCTION SETBULKBCEASY]
DORAND 5
TRY TAG.ITEM<ARGN1>=i_bow
TRY TAG.ITEM<ARGN1>=i_crossbow
TRY TAG.ITEM<ARGN1>=i_ARROW
TRY TAG.ITEM<ARGN1>=i_xbolt
TRY TAG.ITEM<ARGN1>=i_crossbow_heavy
ENDDO

//////////////////////////////////////

[ITEMDEF 8792]
DEFNAME=i_bulk_order_deed
TYPE=t_normal
NAME=Bulk Order Deed
WEIGHT=2
VALUE=1000

ON=@Dclick
DIALOG d_BULK_ORDER
RETURN 1

ON=@Targon_Ground
RETURN 1

ON=@Targon_Item
IF !(<SRC.TAG0.EVENT.ID>)
	IF (<SRC.TARG.CONT>)
		IF (<SRC.TARG.TOPOBJ.UID>==<SRC>)
			FOR 4
				IF (<TAG0.ITEM<dLOCAL._FOR>> == <SRC.TARG.BASEID>)
					IF (<MOREY>)
						IF (<SRC.TARG.QUALITY> < 200)
						SRC.SYSMESSAGE @55 This item is not exceptional!
						DIALOG d_BULK_ORDER
						RETURN 1
						ENDIF
					ENDIF
					IF (!(<ISEMPTY <TAG.MATERIALTOBEMADE>>))
						IF (!(STRMATCH(<TAG.MATERIALTOBEMADE>*,<SRC.TARG.NAME>)))
						DIALOG d_BULK_ORDER
						RETURN 1
						ENDIF
					ENDIF
					IF (<TAG0.ITEM<dLOCAL._FOR>.FEITO> < <MORE1>) && !(<LOCAL.AUMENTOU>)
					TRY TAG0.ITEM<dLOCAL._FOR>.FEITO=<EVAL <TAG0.ITEM<dLOCAL._FOR>.FEITO>+1>
					LOCAL.AUMENTOU=1
					SRC.TARG.CONSUME 1
					ENDIF
				ENDIF
			ENDFOR
		ENDIF
	ENDIF
DIALOG d_BULK_ORDER
TARGET
ENDIF
RETURN 1

ON=@Dropon_Char
IF (<ARGO.BASEID> == <TAG0.VENDORID>)
	FOR 4
		IF (<TAG0.ITEM<dLOCAL._FOR>.FEITO> == <MORE1>)
		LOCAL.OK ++
		ENDIF
	ENDFOR
	IF (<MORE1> == 4) && (<LOCAL.OK> != 4)
	LOCAL.OK=0
	ENDIF
	IF (<LOCAL.OK>)
	REF1=<ARGO.UID>
	REF1.SAY @0ad Well done <SRC.NAME>! Here's the reward.
	SRC.NEWGOLD=<R2500,4000>
	SRC.FAME += <EVAL (<MORE1>*50)>
	SRC.RANDBULKITEM <QVAL <ISEMPTY <TAG.MATERIALTOBEMADE>> ? 0:1> <MOREZ>
	CONSUME 1
	ELSE
	RETURN 1
	ENDIF
ELSE
RETURN 1
ENDIF

///////////////////////////

[DIALOG d_BULK_ORDER]
250,200
src.closealldialogs
PAGE 0
resizepic 10 10 5054 470 230
resizepic 20 20 5120 450 210
checkertrans 20 20 450 210
IF (<MORE2> == 1)
tilepichue 395 70 <serv.itemdef.<tag0.item1>.id> <eval <tag0.cor>>
ENDIF
gumppic 0 5 10460
gumppic 460 5 10460
gumppic 0 220 10460
gumppic 460 220 10460
dtext 170 20 1152 <NAME>
dtext 40 45 1152 Amount to make:            <dMORE1>
dtext 40 70 1152 Item to make:
dtext 245 70 1152 Amount made:
IF (<MORE2> == 1)
dtext 40 95 1152 <SERV.ITEMDEF.<TAG0.ITEM1>.NAME>
dtext 245 95 1152 <EVAL <TAG0.ITEM1.FEITO>>
dtext 40 125 1152 Caracteristics to be met:
	IF (!(<ISEMPTY <TAG.MATERIALTOBEMADE>>)) && !(<MOREY>)
	dtext 40 150 1152 All items must be done with <TAG.MATERIALTOBEMADE>.
	ELIF (!(<ISEMPTY <TAG.MATERIALTOBEMADE>>)) && (<MOREY>)
	dtext 40 150 1152 All items must be done with <TAG.MATERIALTOBEMADE>.
	dtext 40 170 1152 All items must be exceptional.
	ELIF (<MOREY>) && !(<MOREX>)
	dtext 40 150 1152 All items must be exceptional.
	ENDIF
ELSE
dtext 40 95 1152 <SERV.ITEMDEF.<TAG0.ITEM1>.NAME>
dtext 40 115 1152 <SERV.ITEMDEF.<TAG0.ITEM2>.NAME>
dtext 40 135 1152 <SERV.ITEMDEF.<TAG0.ITEM3>.NAME>
dtext 40 155 1152 <SERV.ITEMDEF.<TAG0.ITEM4>.NAME>
dtext 245 95 1152 <dTAG0.ITEM1.FEITO>
dtext 245 115 1152 <dTAG0.ITEM2.FEITO>
dtext 245 135 1152 <dTAG0.ITEM3.FEITO>
dtext 245 155 1152 <dTAG0.ITEM4.FEITO>
	IF (!(<ISEMPTY <TAG.MATERIALTOBEMADE>>))
	dtext 40 175 1152 All items must be done with <TAG.MATERIALTOBEMADE>.
	ELIF (<MOREY>) && !(<MOREX>)
	dtext 40 175 1152 All items must be exceptional.
	ENDIF
ENDIF
button 90 200 4005 4006 1 0 1
dtext 125 200 1152 Combine the item with the deed.

[DIALOG d_BULK_ORDER BUTTON]
ON=1
TARGET @55 What item to combine?

//////////////////////////

[ITEMDEF i_bulk_request_timer]
ID=i_memory
TYPE=t_eq_script
NAME=Bulk Order Deed Timer

ON=@Equip
IF (<SRC.<MORE1>> <= 60.0)
TIMER=<HVAL 60*60*2>
ELSE
TIMER=<HVAL 60*60*4>
ENDIF

ON=@Timer
CONT.SYSMESSAGE @946,3,1 You are eligable to get another bulk order deed.
REMOVE
RETURN 1

///////////////////////////

[ITEMDEF 8793]
DEFNAME=i_bulk_order_book
NAME=Book Older Book
TYPE=T_CONTAINER
TDATA2=03c
VALUE=30

///////////////////////////
////////Prêmios///////////

[ITEMDEF i_leather_gloves_mining]
ID=i_leather_gloves
NAME=Leather gloves of mining
DYE=1

ON=@Create
HITPOINTS=100

ON=@Equip
SRC.MINING ++.0

ON=@UnEquip
SRC.MINING --.0

ON=@ClientToolTip
SRC.ADDCLILOC 1060451,Mining,1

[ITEMDEF i_studded_gloves_mining]
ID=i_studded_gloves
NAME=Studded gloves of mining
DYE=1

ON=@Create
HITPOINTS=100

ON=@Equip
SRC.MINING += 3.0

ON=@UnEquip
SRC.MINING -= 3.0

ON=@ClientToolTip
SRC.ADDCLILOC 1060451,Mining,3

[ITEMDEF i_ringmail_gloves_mining]
ID=i_ringmail_gloves
NAME=Ringmail gloves of mining
DYE=1

ON=@Create
HITPOINTS=100

ON=@Equip
SRC.MINING += 6.0

ON=@UnEquip
SRC.MINING -= 6.0

ON=@ClientToolTip
SRC.ADDCLILOC 1060451,Mining,6

[ITEMDEF i_ancient_smithy_hammer]
ID=i_hammer_smith
NAME=Ancient smithy hammer
DYE=1
TEVENTS=T_LUCK_ITEM
TAG.LUCK=100
TAG.CHARGES=120

ON=@Create
COLOR=0481
MORE2=<HVAL {100 5 150 4 300 3 600 1}>
HITPOINTS=255

ON=@ClientToolTip
SRC.ADDCLILOC 1060451,Blacksmithing,<EVAL <MORE2>/10>
SRC.ADDCLILOC 1060584,<dTAG0.CHARGES>

ON=@Dclick
IF (<TOPOBJ.UID> == <SRC.UID>) && (<CONT> != <SRC>)
SRC.EQUIP <UID>
RETURN 1
ELIF (<CONT> == <SRC>)
DIALOG d_newcraft_dialog_bs
RETURN 1
ENDIF

ON=@Equip
SRC.BLACKSMITHING += <MORE2>

ON=@UnEquip
SRC.BLACKSMITHING -= <MORE2>

[ITEMDEF i_colored_anvil]
ID=i_anvil
NAME=an anvil
DYE=1

ON=@Create
COLOR=colors_all

[ITEMDEF i_powder_Temperment]
ID=i_reag_sulfur_ash
NAME=Powder of Temperment
TYPE=T_NORMAL

ON=@Create
COLOR=60

ON=@Dclick
TARGET @55 What item to enchant?
RETURN 1

ON=@Targon_Item
IF (<SRC.TARG.CONT>)
	IF (<SRC.TARG.TOPOBJ.UID>==<SRC>)
		IF ((<SRC.TARG.ISARMOR>) || (<SRC.TARG.ISWEAPON>)) && (<SRC.TARG.MAXHITS> < 255)
			IF (<EVAL <SRC.TARG.MAXHITS>+10> <= 255)
			SRC.TARG.MAXHITS += 10
			ELSE
			SRC.TARG.MAXHITS=255
			ENDIF
		SRC.TARG.HITS=<SRC.TARG.MAXHITS>
		SRC.TARG.UPDATE
		CONSUME 1
		ENDIF
	ENDIF
ENDIF
RETURN 1

[ITEMDEF i_clothing_bless_deed]
ID=i_deed
NAME=Clothing Bless Deed
TYPE=T_NORMAL

ON=@DClick
TARGET @55 What item to enchant?
RETURN 1

ON=@Targon_Item
IF (<SRC.TARG.CONT>)
	IF (<SRC.TARG.TOPOBJ.UID>==<SRC>)
		IF (<SRC.TARG.TYPE>==T_CLOTHING) && !(<SRC.TARG.ATTR>&ATTR_NEWBIE)
		SRC.TARG.ATTR |= attr_newbie
		CONSUME 1
		ENDIF
	ENDIF
ENDIF
RETURN 1

[FUNCTION RANDBULKITEM]
IF (<ARGN1>)
SERV.NEWITEM {i_ancient_smithy_hammer 5 i_powder_Temperment 3 i_clothing_bless_deed 4 i_power_scroll 3}
ELSE
SERV.NEWITEM {i_colored_anvil 5 i_leather_gloves_mining 5 i_studded_gloves_mining 5 i_ringmail_gloves_mining 5 i_powder_Temperment 5}
ENDIF
IF (<NEW.BASEID> == i_power_scroll)
NEW.MORE1=<ARGN2>
NEW.NAME=Power Scroll of <SERV.SKILL.<ARGN2>.NAME> (<NEW.POWERSCROLLNAME>)
ELIF (<NEW.BASEID>==i_powder_Temperment)
NEW.AMOUNT=5
ENDIF
BOUNCE <NEW>
FINDID.i_bulk_request_timer.TIMER

[EOF]