[ITEMDEF i_deed_personal_attendant]
ID=i_deed
NAME=Personal Attendant Contract of Employment
TYPE=T_NORMAL
VALUE=1000

ON=@Create
COLOR=03
ATTR=attr_newbie

ON=@Dclick
IF (<CONT> != <SRC.FINDLAYER.layer_pack>)
SRC.SYSMESSAGELOC -1,1060640
ELSE
	IF (!(<UID.<CONT.REGION.UID>.ISAMULTI>))
	SRC.SYSMESSAGELOC -1,503239
	ELIF (<UID.<CONT.REGION.UID>.MORE1> != <SRC>)
	SRC.SYSMESSAGELOC -1,1062423
	ELSE
	SERV.NEWNPC=C_PERSONAL_ATTENDANT
	NEW.P=<SRC.P>
	NEW.UPDATEX
	NEW.REMOVETIMER=<EVAL 60*60*24*30>
	SRC.TAME <NEW>
	NEW.EVENTS -e_horses
	NEW.FLAGS |= <DEF.statf_conjured>
	NEW.FINDID.i_bonded_check.REMOVE
	SRC.CURFOLLOWER --
	CONSUME 1
	ENDIF
ENDIF
RETURN 1

[CHARDEF C_PERSONAL_ATTENDANT]
NAME=#NAMES_HUMANFEMALE the attendant
ID=C_WOMAN
DESIRES=i_gold
CAN=MT_USEHANDS|MT_EQUIP|MT_FIRE_IMMUNE|MT_NONMOVER
TSPEECH=VENDORS
ARMOR=100
TAG.NOCONTROL=1

on=@create
COLOR=colors_skin
STR=1
INT=0
DEX=0
FAME=0
KARMA=0
FLAGS |= statf_invul
ALLSKILLS=0.0
EQUIPHALO
WEARNPCVENDOR

ON=@ClientToolTip
SRC.ADDCLILOC 1042971,<NAME>
RETURN 1

ON=@NPCSeeNewPlayer
REF1=<UID.<REGION.UID>.MORE1>
IF (!(<REF1>))
REMOVE
RETURN 1
ENDIF
IF (<REF1.UID> != <SRC.UID>)
	DORAND 6
	SAY @,,2 1076075,<REF1.SEX Lord/Lady>,<REF1.NAME>
	SAY @,,2 1076073,<SRC.SEX men/women>,<SRC.SEX women/men>,<SRC.SEX Lord/Lady>,<SRC.NAME>
	SAY @,,2 1076044,<SRC.SEX Lord/Lady>,<SRC.NAME>
	SAY @,,2 1076041,<REF1.SEX Lord/Lady>,<REF1.NAME>
	SAY @,,2 1076040,<REF1.SEX Lord/Lady>,<REF1.SEX Lord/Lady>,<REF1.NAME>
	SAY @,,2 1076048,<SRC.SEX Lord/Lady>,<SRC.NAME>
	ENDDO
ELSE
SAY @,3,1 Welcome back <REF1.NAME>!
ENDIF

ON=@Dclick
REF1=<UID.<REGION.UID>.MORE1>
IF (!(<REF1>))
REMOVE
RETURN 1
ENDIF

ON=@ContextMenuRequest
REF1=<UID.<REGION.UID>.MORE1>
IF (!(<REF1>))
REMOVE
RETURN 1
ENDIF
IF (<SRC> == <REF1>)
SRC.AddContextEntry 300,6129
ENDIF

ON=@ContextMenuSelect
REF1=<UID.<REGION.UID>.MORE1>
IF (<ARGN1> == 300)
	IF (<SRC> == <REF1>)
	LOCAL.OLDNEW=<NEW>
	SERV.NEWITEM i_deed_personal_attendant
	NEW.BOUNCE
	REMOVE
	RETURN 1
	ENDIF
ENDIF

[EOF]
