[Spell 110]
DEFNAME=s_Poison_Strike
NAME=Poison Strike
SOUND=0
RUNES=
CAST_TIME=1.7
RESOURCES=1 i_reag_nox_crystal
RUNE_ITEM=0
SCROLL_ITEM=0
FLAGS=spellflag_playeronly|spellflag_targ_char|spellflag_harm|spellflag_targ_noself
EFFECT_ID=
EFFECT=
DURATION=0.0
MANAUSE=17
SKILLREQ=SKILL_NECROMANCY 50.0
INTERRUPT=0.0,0.0

ON=@Start
IF (<ISPLAYER>)
SAY @,3,1 In Vas Nox
ENDIF

ON=@Effect
IF (<SRC> == <UID>)
RETURN 1
ENDIF
SRC.SOUND=0229
IF (<SRC.TAG0.MAGICDAMINCREASE>)
LOCAL.ITEMSPELLDAMAGEINCREASE=<SRC.TAG0.MAGICDAMINCREASE>
	IF (<ISPLAYER>)
		IF (<LOCAL.ITEMSPELLDAMAGEINCREASE> > 15)
		LOCAL.ITEMSPELLDAMAGEINCREASE=15
		ENDIF
	ENDIF
ENDIF
LOCAL.DAMAGE=<FEVAL <FLOATVAL ((<R32,40>*((300+(<SRC.NECROMANCY>*9))/1000))*(1+(<LOCAL.ITEMSPELLDAMAGEINCREASE>/100)))>>
DAMAGE <LOCAL.DAMAGE> <DEF.DAM_MAGIC> <SRC>
SPELLEFFECT S_POISON,<EVAL <SRC.POISONING>+50.0>,<SRC>
EFFECT 3,036B0,16,30,0,63
LOCAL.AFFECTED=<UID>
FORCHARS 2
	IF (<UID> != <LOCAL.AFFECTED>) && (<UID> != <SRC>)
		IF (!(<ISBENEFICIAL <SRC>>))
		LOCAL.SECONDDAMAGE=<EVAL (<LOCAL.DAMAGE>/(<DISTANCE <LOCAL.AFFECTED>>+1))>
		DAMAGE <LOCAL.SECONDDAMAGE> <DEF.DAM_MAGIC> <SRC>
		EFFECT 3,036B0,16,30,0,63
		ENDIF
	ENDIF
ENDFOR

[EOF]