//Part of this is also handled on e_player.scp

[EVENTS E_ENEMY_OF_ONE]
ON=@Hit
IF (<ISEMPTY <TAG.ENEMYOFONE.TARGET>>)
TAG.ENEMYOFONE.TARGET=<SRC.BASEID>
REMOVEBUFF 1011
LOCAL.DELAY=<F_COMPUTE_POWERLEVEL 1>
ADDBUFF 1011 1075653 1075654 <dLOCAL.DELAY> 50 100
ENDIF

ON=@DeathCorpse
FINDID.i_enemyofone_timer.TIMER=1

[ITEMDEF i_enemyofone_timer]
ID=i_memory
TYPE=T_EQ_SCRIPT
NAME=Enemy of One

ON=@Timer
CONT.REMOVEBUFF 1011
CONT.EVENTS -E_ENEMY_OF_ONE
CONT.TAG.ENEMYOFONE.TARGET=
REMOVE
RETURN 1

[Spell 206]
DEFNAME=s_Enemy_of_One
NAME=Enemy of One
SOUND=00F5
RUNES=
CAST_TIME=0.5
RESOURCES=
RUNE_ITEM=0
SCROLL_ITEM=0
FLAGS=spellflag_playeronly|spellflag_nofreezeoncast|spellflag_no_castanim
EFFECT_ID=0376A
EFFECT=10
DURATION=0.0
MANAUSE=20
SKILLREQ=SKILL_CHIVALRY 45.0
INTERRUPT=0.0,0.0

ON=@Start
SAY @,,2 1060723

ON=@Effect
SOUND=01ED
EFFECT 3,0375A,3,30,0,43,3
EFFECT 3,037B9,3,30,0,43
LOCAL.DELAY=<F_COMPUTE_POWERLEVEL 1>
IF (<LOCAL.DELAY> > <EVAL (60*35)/10>)
LOCAL.DELAY=210
ENDIF
REMOVEBUFF 1011
TAG.ENEMYOFONE.TARGET=
EVENTS -E_ENEMY_OF_ONE
IF (<FINDID.i_enemyofone_timer>)
FINDID.i_enemyofone_timer.TIMER=<LOCAL.DELAY>
ELSE
SERV.NEWITEM i_enemyofone_timer,1,<UID>
NEW.TIMER=<LOCAL.DELAY>
ENDIF
EVENTS +E_ENEMY_OF_ONE
ADDBUFF 1011 1060498 1075902 <dLOCAL.DELAY> 50 100

[EOF]