[FUNCTION helppage]
IF !(<TAG0.EVENT.ID> >= 100)
SDIALOG d_help_menu
ENDIF

[function help]
IF !(<TAG0.EVENT.ID> >= 100)
SDIALOG d_help_menu
ENDIF

[DIALOG d_help_menu]
150, 70
src.closealldialogs
PAGE 0
resizepic 50 60 2600 485 400
CHECKERTRANS 50 60 485 400
gumppic 380 100 12 1002
gumppic 380 100 0c544
gumppic 380 100 0c5c4 36
gumppic 380 100 0ee3b <eval 0480>
dhtmlgump 240 80 200 125 0 0 <def.BIG><def.BFONT_SIZE7><def.BFONT_LGREEN><serv.servname><def.bige>
button 80 120 2151 2152 1 0 1
dhtmlgump 120 110 300 62 1 1 <def.BFONT_BLACK>If you are stuck on the cenary, just use this option. You'll be teleported to the Help Room in <def.u><def.BFONT_GREEN>3 minutes, or 10 seconds if you are dead<def.ue>. If you logout, enter an event, or receive a blow the timer will be canceled.
button 80 200 2151 2152 1 0 2
dhtmlgump 120 190 300 62 1 1 <def.BFONT_BLACK>If you are having any doubts about the server, just visit our website.
button 80 280 2151 2152 1 0 3
dhtmlgump 120 270 300 62 1 1 <def.BFONT_BLACK>Found a bug on the server? Send a GM Page to the staff and as soon as possible a staff member will try to solve it and give you an answer. Try to make your pages clear and small. <DEF.BFONT_YELLOW>DO NOT <DEF.BFONT_BLACK>use this system to ask for events or any kind of privileges, this is punishable.
dtext 75 350 2010 Any unclarified doubt, just look for players or our Staff
//dtext 70 370 2010 or the staff in our Mirc Channel:
//dtext 160 390 38 #ExodusUOBR - BRLINK.ORG
dhtmlgump 350 420 300 62 0 0 <Def.BFONT_WHITE>Online Count: <def.b><serv.clients><def.be>
button 315 413 2151 2152 1 0 4

[DIALOG d_help_menu BUTTON]
on=1
if (<findid.i_teleport_delay>)
sysmessage @036 You're already waiting <eval <findid.i_teleport_delay.tag.temporestante>> minutes to go to the Help Room.
elif (<tag0.event.id>) || (<findid.i_pvp_time>) || (<flags>&statf_freeze) || !(STRCMPI(<REGION.NAME>,Destroyer Arena)) || !(STRCMPI(<REGION.NAME>,Doom Gauntlet))
sysmessage @0ad You can't go to the Help Room.
else
serv.newitem i_teleport_delay
equip <new>
IF !(<FLAGS>&statf_dead)
SYSMESSAGE @0ad In 3 minutes you'll be teleported to the Help Room.
ELSE
SYSMESSAGE @0ad In 10 seconds you'll be teleported to the Help Room.
NEW.TIMER 10
NEW.MORE1=2
ENDIF
events +e_teleport_room
endif

on=2
weblink=<serv.url>

ON=3
gmpage

on=4
I.ONLINE

//////////////////////////

[EVENTS e_teleport_room]
ON=@logout
findid.i_teleport_delay.remove
events -e_teleport_room

ON=@GetHit
sysmessage @946,3,1 You got damaged, your teleport to the Help Room has been canceled.
findid.i_teleport_delay.remove
events -e_teleport_room

///////////////

[DIALOG help_room2]
13, 30
src.closealldialogs
PAGE 0
resizepic 73 150 3500 250 90
tilepic 260 150 3273
button 85 198 2117 2118 1 0 0
button 85 168 2117 2118 1 0 1
dtext 104 164 270 Go to Help Room.
dtext 103 194 270 Don't want to go anymore

[DIALOG help_room2 BUTTON]
on=0
events -e_teleport_room
sysmessage @55 Help Room caceled!

on=1
IF (<tag0.event.id>) || (<findid.i_pvp_time>) || (<flags>&statf_freeze) || !(STRCMPI(<REGION.NAME>,Destroyer Arena)) || !(STRCMPI(<REGION.NAME>,Doom Gauntlet))
events -e_teleport_room
sysmessage @55 Help Room caceled!
ELSE
sysmessage @55 You went to the Help Room.
events -e_teleport_room
go Help Room
resurrect
ENDIF

///////////////////////

[ITEMDEF i_teleport_delay]
NAME=Delay Teleport
ID=i_memory
TYPE=T_EQ_SCRIPT

ON=@Create
ATTR=attr_decay

ON=@Equip
tag.temporestante=3
TIMER=120
more1=1
link=<src>
src.events=+e_teleport_room
	
ON=@Timer
if (<topobj.findid.i_pvp_time>)
topobj.sysmessage @0488 You can't go to the Help Room while in a PVP Arena.
remove
ELIF (<topobj.tag0.event.id>)
topobj.sysmessage @0488 You can't go to the Help Room in the middle of a <var.event.name>
remove
ELIF  !(STRCMPI(<topobj.REGION.NAME>,Destroyer Arena))
topobj.sysmessage @0488 You can't go to the Help Room from here.
remove
ELIF (<more1>==1)
topobj.sysmessage @0ad 1 minute left for you to go to the Help Room.
tag.temporestante=1
timer=60
more1=2
ELIF (<more1>==2)
topobj.events -e_teleport_room
topobj.dialog_up help_room2
remove
ENDIF
return 1

ON=@Dropon_Item
CONT=<SRC.UID>
RETURN 1

[EOF]