[TYPEDEF t_status_bonus]
ON=@ClientToolTip
IF (<TAG0.MANAINCREASE>)
SRC.ADDCLILOC 1060439,<dTAG0.MANAINCREASE>
ENDIF
IF (<TAG0.HITSINCREASE>)
SRC.ADDCLILOC 1060431,<dTAG0.HITSINCREASE>
ENDIF
IF (<TAG0.STAMINCREASE>)
SRC.ADDCLILOC 1060484,<dTAG0.STAMINCREASE>
ENDIF
IF (<TAG0.INTINCREASE>)
SRC.ADDCLILOC 1060432,<dTAG0.INTINCREASE>
ENDIF
IF (<TAG0.STRINCREASE>)
SRC.ADDCLILOC 1060485,<dTAG0.STRINCREASE>
ENDIF
IF (<TAG0.DEXINCREASE>)
SRC.ADDCLILOC 1060409,<dTAG0.DEXINCREASE>
ENDIF
IF (!(<ISEMPTY <TAG.SKILLINCREASE>>))
SRC.ADDCLILOC 1060451,<TAG.SKILLINCREASE>,<EVAL <TAG0.SKILLINCREASEVALUE>/10>
ENDIF
IF (!(<ISEMPTY <TAG.SKILLINCREASE2>>))
SRC.ADDCLILOC 1060453,<TAG.SKILLINCREASE2>,<EVAL <TAG0.SKILLINCREASEVALUE2>/10>
ENDIF
IF (<TAG0.MANAREGENERATION>)
SRC.ADDCLILOC 1060440,<dTAG0.MANAREGENERATION>
ENDIF
IF (<TAG0.HITSREGENERATION>)
SRC.ADDCLILOC 1060444,<dTAG0.HITSREGENERATION>
ENDIF
IF (<TAG0.STAMREGENERATION>)
SRC.ADDCLILOC 1060443,<dTAG0.STAMREGENERATION>
ENDIF

ON=@Equip
IF (<TAG0.INTINCREASE>)
SRC.MODINT += <TAG0.INTINCREASE>
SRC.MAXMANA += <TAG0.INTINCREASE>
ENDIF
IF (<TAG0.STRINCREASE>)
SRC.MODSTR += <TAG0.STRINCREASE>
SRC.MAXHITS += <EVAL <TAG0.STRINCREASE>/2>
ENDIF
IF (<TAG0.DEXINCREASE>)
SRC.MODDEX += <TAG0.DEXINCREASE>
SRC.MAXSTAM += <TAG0.DEXINCREASE>
ENDIF
IF (<TAG0.MANAINCREASE>)
SRC.MAXMANA += <TAG0.MANAINCREASE>
ENDIF
IF (<TAG0.HITSINCREASE>)
SRC.MAXHITS += <TAG0.HITSINCREASE>
ENDIF
IF (<TAG0.STAMINCREASE>)
SRC.MAXSTAM += <TAG0.STAMINCREASE>
ENDIF
IF (!(<ISEMPTY <TAG.SKILLINCREASE>>))
TRY SRC.<TAG0.SKILLINCREASE>=<EVAL <SRC.<TAG.SKILLINCREASE>>+<dTAG0.SKILLINCREASEVALUE>>
ENDIF
IF (!(<ISEMPTY <TAG.SKILLINCREASE2>>))
TRY SRC.<TAG0.SKILLINCREASE2>=<EVAL <SRC.<TAG.SKILLINCREASE2>>+<dTAG0.SKILLINCREASEVALUE2>>
ENDIF
IF (<TAG0.MANAREGENERATION>)
SRC.TAG0.ITEMMANAREGEN += <TAG0.MANAREGENERATION>
ENDIF
IF (<TAG0.HITSREGENERATION>)
SRC.TAG0.ITEMHITSREGEN += <TAG0.HITSREGENERATION>
ENDIF
IF (<TAG0.STAMREGENERATION>)
SRC.TAG0.ITEMSTAMREGEN += <TAG0.STAMREGENERATION>
ENDIF

ON=@UnEquip
IF (<TAG0.INTINCREASE>)
SRC.MODINT -= <TAG0.INTINCREASE>
SRC.MAXMANA -= <TAG0.INTINCREASE>
ENDIF
IF (<TAG0.STRINCREASE>)
SRC.MODSTR -= <TAG0.STRINCREASE>
SRC.MAXHITS -= <EVAL <TAG0.STRINCREASE>/2>
ENDIF
IF (<TAG0.DEXINCREASE>)
SRC.MODDEX -= <TAG0.DEXINCREASE>
SRC.MAXSTAM -= <TAG0.DEXINCREASE>
ENDIF
IF (<TAG0.MANAINCREASE>)
SRC.MAXMANA -= <TAG0.MANAINCREASE>
ENDIF
IF (<TAG0.HITSINCREASE>)
SRC.MAXHITS -= <TAG0.HITSINCREASE>
ENDIF
IF (<TAG0.STAMINCREASE>)
SRC.MAXSTAM -= <TAG0.STAMINCREASE>
ENDIF
IF (!(<ISEMPTY <TAG.SKILLINCREASE>>))
TRY SRC.<TAG0.SKILLINCREASE>=<EVAL <SRC.<TAG.SKILLINCREASE>>-<dTAG0.SKILLINCREASEVALUE>>
ENDIF
IF (!(<ISEMPTY <TAG.SKILLINCREASE2>>))
TRY SRC.<TAG0.SKILLINCREASE2>=<EVAL <SRC.<TAG.SKILLINCREASE2>>-<dTAG0.SKILLINCREASEVALUE2>>
ENDIF
IF (<TAG0.MANAREGENERATION>)
SRC.TAG0.ITEMMANAREGEN -= <TAG0.MANAREGENERATION>
	IF (!(<SRC.TAG0.ITEMMANAREGEN>))
	SRC.TAG.ITEMMANAREGEN=
	ENDIF
ENDIF
IF (<TAG0.HITSREGENERATION>)
SRC.TAG0.ITEMHITSREGEN -= <TAG0.HITSREGENERATION>
	IF (!(<SRC.TAG0.ITEMHITSREGEN>))
	SRC.TAG.ITEMHITSREGEN=
	SRC.FINDID.i_focus_mem.TAG.HITSREGEN=
	ENDIF
ENDIF
IF (<TAG0.STAMREGENERATION>)
SRC.TAG0.ITEMSTAMREGEN -= <TAG0.STAMREGENERATION>
	IF (!(<SRC.TAG0.ITEMSTAMREGEN>))
	SRC.TAG.ITEMSTAMREGEN=
	ENDIF
ENDIF

[EOF]