[DIALOG d_cartography_ruo]
300,180
src.closealldialogs

PAGE 1
resizepic 10 10 3600 500 400
checkertrans 10 10 500 400
button 30 40 4005 4006 1 0 2
dtext 65 40 1152 Treasure Map
button 30 70 4005 4006 1 0 3
dtext 65 70 1152 Detail Map
button 30 100 4005 4006 1 0 4
dtext 65 100 1152 Regional Map
button 30 130 4005 4006 1 0 5
dtext 65 130 1152 Sea Chart
button 30 160 4005 4006 1 0 6
dtext 65 160 1152 Full World Map

resizepic 30 290 3600 400 110
checkertrans 30 290 400 110
IF !(<ISEMPTY <CTAG.LASTITEM.CART>>)
dtext 50 310 88 Last item: <SERV.ITEMDEF.<CTAG.LASTITEM.CART>.NAME>
dtext 50 330 88 Resources: <SERV.ITEMDEF.<CTAG.LASTITEM.CART>.RESMAKE>
button 50 360 4005 4006 1 0 1
dtext 80 360 88 Make last
tilepic 300 330 <SERV.ITEMDEF.<CTAG.LASTITEM.CART>.ID>
ENDIF

resizepic 10 400 3600 500 100
checkertrans 10 400 500 100
dtext 220 410 33 Messages:
IF !(<ISEMPTY <CTAG.RUO.MSG>>)
dhtmlgump 30 430 440 60 0 0 <DEF.BFONT_WHITE><CTAG.RUO.MSG>
ENDIF

[DIALOG d_cartography_ruo BUTTON]
ON=0
CTAG.RUO.MSG

ON=1
IF !(<CANMAKESKILL <CTAG.LASTITEM.CART>>)
CTAG.RUO.MSG You don't have the necessary skill levels required to make this item.
ELIF !(<CANMAKE <CTAG.LASTITEM.CART>>)
CTAG.RUO.MSG You don't have the necessary materials to make this item.
ELSE
IF (<ACTION>==-1)
MAKEITEM <CTAG.LASTITEM.CART>
CTAG.RUO.MSG You start to craft the item.
ELSE
CTAG.RUO.MSG You can only do this when you're less occupied.
ENDIF
ENDIF
SDIALOG d_cartography_ruo

ON=2
CTAG.RUO.MSG It is not possible to craft treasure maps anymore.
SDIALOG d_cartography_ruo

ON=3 6
CALL RUO_CART_SELECT <HVAL <ARGN>-2>
IF !(<FINDID.i_map_blank>)
CTAG.RUO.MSG You must have a blank map to craft this item.
ELIF !(<CARTOGRAPHY> >= <LOCAL.SKILL>)
CTAG.RUO.MSG You don't have the necessary skill levels required to make this item.
ELSE
IF (<ACTION>==-1)
DRAWMAP <LOCAL.ITEM>
CTAG.RUO.MSG You start to craft the item.
CTAG.LASTITEM.CART i_map
ELSE
CTAG.RUO.MSG You can only do this when you're less occupied.
ENDIF
ENDIF
SDIALOG d_cartography_ruo

[FUNCTION RUO_CART_SELECT]
IF (<ARGN>==1)
LOCAL.ITEM=200
LOCAL.SKILL=50
ELIF (<ARGN>==2)
LOCAL.ITEM=400
LOCAL.SKILL=300
ELIF (<ARGN>==3)
LOCAL.ITEM=800
LOCAL.SKILL=450
ELIF (<ARGN>==4)
LOCAL.ITEM=2048
LOCAL.SKILL=750
ENDIF

[EOF]