SphereCommunity

Time to share some scripts we use frequently on TUP. Some may be in need of updating.

This may be a common script, I am not sure. It will show your equipment in an alternative gump. Guess it might help to see layers or make it easy to unequip smaller items.

Use: .eq
Code:

//********************************************************************//

//                         EQUIPMENT LIST                             //

//  DISPLAYS A LIST OF EVERYTHING EQUIPPED & OFFERS BASIC FUNCTIONS.  //

//********************************************************************//

[FUNCTION eq]

  SRC.DIALOG_eq_list

[FUNCTION DIALOG_eq_list]

  if ( <SRC.ISDEAD> )

     src.sysmessage You can't do this while dead.

     return 1

  endif

  TAG.EQ.LAYER    = 0

  VAR.PAGE1    = 2

  VAR.PAGE2    = 1

  if ( strcmp( "<args>", "" ) )

     if ( <src.findlayer(<args>).uid> )

        TAG.EQ.LAYER    = <args>

        VAR.PAGE1    = 0

        VAR.PAGE2    = 1

     endif

  endif

  DIALOG D_eq_list

[FUNCTION eq_layer_select]

   if !( <src.findlayer(<args>).uid> )

      SRC.DIALOG_EQ_LIST

   else

      SRC.DIALOG_EQ_LIST <args>

   endif

[FUNCTION eq_layer_color]

  if ( <eval <args>> == <eval <SRC.TAG.EQ.LAYER>> )

     var.eq_layer_color    = 52

  else

     var.eq_layer_color    = 0

  endif

  return <var.eq_layer_color>

//********************************************************************//

[DIALOG d_eq_list]

100, 40

NOMOVE

page <VAR.PAGE1>

  resizepic  370 324 2600 340 160 // item detail

  dtext   220  27  0 Equipment

  dtext   520 410  0 Unequip

  gumppic 522 351  <eval 0db>

  button  520 350  <eval 0db> <eval 0102> 1 0 50

  dtext   450 445  0 Use

  gumppic 442 381  <eval 0ec>

  button  440 380  <eval 0ec> <eval 0102> 1 0 51

  dtext    610 445 0 Look

  gumppic 602 381 <eval 0e3>

  button  600 380 <eval 0e3> <eval 0102> 1 0 52

page <VAR.PAGE2>

  resizepic 0 0 2600 420 484 // Curved Grey background 

  dtext   20 60 46 Head

  dtext   100 60 <eval <eq_layer_color 6>> <qval <src.findlayer(6).uid> ? <src.findlayer(6).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(6).uid> ? 63 : 25> <eval tp_btup> <eval tp_btdn> 1 0 6

  dtext   20 78 46 Ears

  dtext   100 78 <eval <eq_layer_color 18>> <qval <src.findlayer(18).uid> ? <src.findlayer(18).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(18).uid> ? 81 : 25> <eval tp_btup> <eval tp_btdn> 1 0 18

  dtext   20 96 46 Neck

  dtext   100 96 <eval <eq_layer_color 10>> <qval <src.findlayer(10).uid> ? <src.findlayer(10).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(10).uid> ? 99 : 25> <eval tp_btup> <eval tp_btdn> 1 0 10

  dtext   20 114 46 Arms

  dtext   100 114 <eval <eq_layer_color 19>> <qval <src.findlayer(19).uid> ? <src.findlayer(19).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(19).uid> ? 117 : 25> <eval tp_btup> <eval tp_btdn> 1 0 19

  dtext   20 132 46 Hands

  dtext   100 132 <eval <eq_layer_color 7>> <qval <src.findlayer(7).uid> ? <src.findlayer(7).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(7).uid> ? 135 : 25> <eval tp_btup> <eval tp_btdn> 1 0 7

  dtext   20 150 46 Wrist

  dtext   100 150 <eval <eq_layer_color 14>> <qval <src.findlayer(14).uid> ? <src.findlayer(14).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(14).uid> ? 153 : 25> <eval tp_btup> <eval tp_btdn> 1 0 14

  dtext   20 168 46 Finger

  dtext   100 168 <eval <eq_layer_color 8>> <qval <src.findlayer(8).uid> ? <src.findlayer(8).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(8).uid> ? 171 : 25> <eval tp_btup> <eval tp_btdn> 1 0 8

  dtext   20 186 46 Chest

  dtext   100 186 <eval <eq_layer_color 5>> <qval <src.findlayer(5).uid> ? <src.findlayer(5).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(5).uid> ? 189 : 25> <eval tp_btup> <eval tp_btdn> 1 0 5

  dtext   100 201 <eval <eq_layer_color 13>> <qval <src.findlayer(13).uid> ? <src.findlayer(13).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(13).uid> ? 204 : 25> <eval tp_btup> <eval tp_btdn> 1 0 13

  dtext   20 222 46 Waist

  dtext   100 222 <eval <eq_layer_color 12>> <qval <src.findlayer(12).uid> ? <src.findlayer(12).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(12).uid> ? 225 : 25> <eval tp_btup> <eval tp_btdn> 1 0 12

  dtext   20 240 46 Legs

  dtext   100 240 <eval <eq_layer_color 4>> <qval <src.findlayer(4).uid> ? <src.findlayer(4).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(4).uid> ? 243 : 25> <eval tp_btup> <eval tp_btdn> 1 0 4

  dtext   100 255 <eval <eq_layer_color 24>> <qval <src.findlayer(24).uid> ? <src.findlayer(24).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(24).uid> ? 248 : 25> <eval tp_btup> <eval tp_btdn> 1 0 24

  dtext   100 270 <eval <eq_layer_color 23>> <qval <src.findlayer(23).uid> ? <src.findlayer(23).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(23).uid> ? 273 : 25> <eval tp_btup> <eval tp_btdn> 1 0 23

  dtext   20 294 46 Feet

  dtext   100 294 <eval <eq_layer_color 3>> <qval <src.findlayer(3).uid> ? <src.findlayer(3).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(3).uid> ? 297 : 25> <eval tp_btup> <eval tp_btdn> 1 0 3

  dtext   20 312 46 Tunic

  dtext   100 312 <eval <eq_layer_color 17>> <qval <src.findlayer(17).uid> ? <src.findlayer(17).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(17).uid> ? 315 : 25> <eval tp_btup> <eval tp_btdn> 1 0 17

  dtext   20 330 46 Cape

  dtext   100 330 <eval <eq_layer_color 20>> <qval <src.findlayer(20).uid> ? <src.findlayer(20).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(20).uid> ? 333 : 25> <eval tp_btup> <eval tp_btdn> 1 0 20

  dtext   20 348 46 Robe

  dtext   100 348 <eval <eq_layer_color 22>> <qval <src.findlayer(22).uid> ? <src.findlayer(22).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(22).uid> ? 351 : 25> <eval tp_btup> <eval tp_btdn> 1 0 22

  dtext   20 366 46 Holding

  dtext   100 366 <eval <eq_layer_color 1>> <qval <src.findlayer(1).uid> ? <src.findlayer(1).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(1).uid> ? 369 : 25> <eval tp_btup> <eval tp_btdn> 1 0 1

  dtext   100 381 <eval <eq_layer_color 2>> <qval <src.findlayer(2).uid> ? <src.findlayer(2).name> : <VAR.BLANKLINE>>

  button  85 <qval <src.findlayer(2).uid> ? 384 : 25> <eval tp_btup> <eval tp_btdn> 1 0 2

  dtext  120 421 0 Open the Travel Papers

  button 100 424 <eval 0d8> <eval 0d7> 1 0 60

  dtext  120 438 0 List reagents in backpack

  button 100 441 <eval 0d8> <eval 0d7> 1 0 61

  dtext  120 455 0 Claim allocated skill points

  button 100 458 <eval 0d8> <eval 0d7> 1 0 62

  resizepic 52  25 5100 319 25        // title background

  resizepic 57 410 5100 319 5        // border

  dtext    185 27 0 Equipment

[DIALOG d_eq_list BUTTON]

ONBUTTON = 1 26

   SRC.EQ_LAYER_SELECT <EVAL <ARGN1>>

ONBUTTON = 50

   SRC.ACT    = <SRC.findlayer(<src.tag.eq.layer>).uid>

   SRC.ACT.UNEQUIP

   SRC.DIALOG_eq_list

ONBUTTON = 51

   SRC.ACT    = <SRC.findlayer(<src.tag.eq.layer>).uid>

   SRC.ACT.DCLICK

ONBUTTON = 52

   SRC.ACT    = <SRC.findlayer(<src.tag.eq.layer>).uid>

   SRC.ACT.TRIGGER @Click

   SRC.DIALOG_eq_list <src.tag.eq.layer>

ONBUTTON = 60

   SRC.PAPERS

ONBUTTON = 61

   SRC.REGS

ONBUTTON = 62

   SRC.CLAIMSKILL
GOOD! I'LL TRY THIS ONE! THX ;]
Ultima One

amonvangrell
