Post Reply 
 
Thread Rating:
  • 0 Votes - 0 Average
  • 1
  • 2
  • 3
  • 4
  • 5
Expo Pots?
Author Message
Reflex
Journeyman
*

Posts: 130
Likes Given: 0
Likes Received: 2 in 2 posts
Joined: Apr 2012
Reputation: 1



Post: #1
Expo Pots?
How do you regulate if explosion pots can blow up other expo pots?
05-21-2012 05:58 AM
Find all posts by this user Like Post Quote this message in a reply
RanXerox
Master
**

Posts: 550
Likes Given: 1
Likes Received: 12 in 9 posts
Joined: Dec 2010
Reputation: 19



Post: #2
RE: Expo Pots?
Make your own:

Code:
[ITEMDEF i_potion_explosionless]
ID=i_bottle_purple
NAME=exploding potion
TYPE=t_thrown_explosive
VALUE=25
WEIGHT=1.0
RESOURCES=i_reag_sulfur_ash 3,1 i_bottle_empty
SKILLMAKE=Alchemy 30.1
CATEGORY=Magic
SUBSECTION=Potions
DESCRIPTION=Explosion (lesser)
ON=@Create
   COLOR=012
   TAG.Damage=6,15
   TAG.Range=1

[ITEMDEF i_potion_explosion]
ID=i_bottle_purple
NAME=exploding potion
TYPE=t_thrown_explosive
VALUE=93
WEIGHT=1.0
RESOURCES=i_reag_sulfur_ash 6,1 i_reag_volcanic_ash,1 i_bottle_empty
SKILLMAKE=Alchemy 60.1
CATEGORY=Magic
SUBSECTION=Potions
DESCRIPTION=Explosion
ON=@Create
   TAG.Damage=16,25
   TAG.Range=2

[ITEMDEF i_potion_explosiongreat]
ID=i_bottle_purple
NAME=exploding potion
TYPE=t_thrown_explosive
VALUE=241
WEIGHT=1.0
RESOURCES=i_reag_sulfur_ash 9,1 i_reag_volcanic_ash 2,1 i_reag_brimstone,1 i_bottle_empty
SKILLMAKE=Alchemy 90.1
CATEGORY=Magic
SUBSECTION=Potions
DESCRIPTION=Explosion (greater)
ON=@Create
   COLOR=014
   TAG.Damage=26,35
   TAG.Range=3

[TYPEDEF t_thrown_explosive]
ON=@DClick
   TARGETG @color_text,,2 1113280//"Which target do you wish to throw this at?"
   RETURN 1
ON=@Targon_Ground
   IF (<SRC.CANSEELOSFLAG 0 <SRC.TARGP>>==0)
      SRC.SYSMESSAGELOC color_text,500237//"Target cannot be seen!"
   ELSEIF (<SRC.DISTANCE <SRC.TARGP>> < 2)
      SRC.SYSMESSAGELOC color_text,1063303//"Your target is too close!"
   ELSEIF (<SRC.DISTANCE <SRC.TARGP>> > 10)
      SRC.SYSMESSAGELOC color_text,1063304//"Your target is too far!"
   ELSE
      SRC.SPELLEFFECT s_reveal,100.0,<SRC>
      SRC.ANIM 11
      P=<SRC.TARGP>
      MORE2=4
      TIMER=1
      EFFECT 0,0f0d,8,16
   ENDIF
   RETURN 1
ON=@Targon_Char
   IF !(<SRC.TARG.CANSEELOS>)
      SRC.SYSMESSAGELOC color_text,500237//"Target cannot be seen!"
   ELSEIF (<SRC.TARG>==<SRC>)
      SRC.SYSMESSAGELOC color_text,1005576//"You can't throw this at yourself."
   ELSEIF (<SRC.CHECKDIST> < 2)
      SRC.SYSMESSAGE color_text,1063303//"Your target is too close!"
   ELSEIF (<SRC.CHECKDIST> > 10)
      SRC.SYSMESSAGELOC color_text,1063304//"Your target is too far!"
   ELSE
      SRC.SPELLEFFECT s_reveal,100.0
      SRC.ANIM 11
      P=<SRC.TARGP>
      MORE2=4
      TIMER=1
      EFFECT 0,0f0d,8,16
   ENDIF
   RETURN 1
ON=@Targon_Item
   SRC.SYSMESSAGE @color_text,,1 You can not target that!
   RETURN 1
ON=@Timer
   MORE2 --
   IF (<MORE2>)
      SAY <dMORE2>
      TIMER=1
   ELSE
      REMOVE
      LINK.SFX 519
      SERV.NEWITEM=i_fx_explode
      NEW.TYPE=t_explosion
      NEW.ATTR=attr_move_never|attr_can_decay
      NEW.LINK=<LINK>   //this should link the explosion to thrower - possibly making them a criminal
      NEW.MOREX=<R<STRARG <TAG0.Damage>>,<STREAT <TAG0.Damage>>>
      NEW.MOREY=dam_fire|dam_general
      NEW.MOREZ=<TAG0.Range>
      NEW.P=<P>
      NEW.TIMERD=1
   ENDIF
   RETURN 1
05-21-2012 08:13 AM
Find all posts by this user Like Post Quote this message in a reply
Post Reply 


Forum Jump:


User(s) browsing this thread: 1 Guest(s)